home *** CD-ROM | disk | FTP | other *** search
/ The Atari Compendium / The Atari Compendium (Toad Computers) (1994).iso / files / prgtools / programm.ing / falcon / nt_dsp1.lzh / NT_DSP1.MSA / CODEC / LOGLIN.ASM < prev    next >
Encoding:
Assembly Source File  |  1989-01-24  |  4.6 KB  |  110 lines
  1. ;
  2. ; This program originally available on the Motorola DSP bulletin board.
  3. ; It is provided under a DISCLAMER OF WARRANTY available from
  4. ; Motorola DSP Operation, 6501 Wm. Cannon Drive W., Austin, Tx., 78735.
  5. ; 
  6. ; Companded CODEC to Linear PCM Data Conversion Macros
  7. ; 
  8. ; Last Update 20 Apr 87   Version 1.0
  9. ;
  10. loglin  ident   1,0
  11. ;
  12. ; These macros convert 8 bit companded data received from CODEC A/D
  13. ; converters used in telecommunications applications to 13 bit, linear
  14. ; fractional data.  The internal mu/a-law lookup tables in the DSP56001
  15. ; X data ROM are used to minimize execution time.  Three companded
  16. ; formats are supported for the Motorola MC14400 CODEC series and
  17. ; similar devices.
  18. ;
  19. ; Macro Calls:          smlin - sign magnitude to linear conversion
  20. ;                               with mu-law companding.
  21. ;                       mulin - mu-law companded to linear conversion.
  22. ;                       allin - a-law companded to linear conversion
  23. ;                               with CCITT (G7.12) format.
  24. ;
  25. ;                       No macro arguments are required.  However, these
  26. ;                       macros assume that the scaling modes are off
  27. ;                       (S1=0, S0=0).
  28. ;
  29. ; Input data is in the 8 most significant bits of a1.  The remaining
  30. ; bits of a are ignored.
  31. ;
  32. ;  -------------------------------------------------------
  33. ; | Sign |    Chord Number    |       Step Number         |
  34. ; | Bit  |                    |                           |
  35. ; |__23__|__22_____21_____20__|__19_____18_____17_____16__|
  36. ;
  37. ; Output data is in the 56 bit accumulator a.  The linear fraction is
  38. ; in the 13 most significant bits of a1 and the 11 least significant
  39. ; bits are zero.
  40. ;
  41. ; Alters Data ALU Registers
  42. ;       x1      x0
  43. ;       a2      a1      a0      a
  44. ;       b2      b1      b0      b
  45. ;
  46. ; Alters Address Registers
  47. ;       r0
  48. ;
  49. ; Alters Program Control Registers
  50. ;       pc      sr
  51. ;
  52. ; Uses 0 locations on System Stack
  53. ;
  54. ; Latest Revision - April 15, 1987
  55. ; Tested and verified - April 20, 1987
  56. ;
  57. ; smlin - sign magnitude to linear conversion
  58. ;
  59. smlin   macro
  60. _shift  equ     $80                     ;shift constant
  61. _mutable        equ     $100            ;base address of mu-law table
  62. ;
  63.         not     a       a1,b            ;invert input bits, save input
  64.         lsl     a       #>_shift,x0     ;shift out sign bit, get shift constant
  65.         lsr     a       #_mutable,x1    ;shift in zero, get table base
  66.         tfr     x1,a    a1,x1           ;swap table base and offset
  67.         mac     x1,x0,a                 ;shift offset down and add to base
  68.         move            a,r0            ;move to address register
  69.         nop
  70.         lsl     b       x:(r0),a        ;c=sign bit, lookup linear data
  71.         neg     a       a,b             ;a=negative result, b=positive result
  72.         tcs     b,a                     ;if pos sign, correct result
  73.         endm
  74. ;
  75. ; mulin - mu-law to linear conversion
  76. ;
  77. mulin   macro
  78. _shift  equ     $80                     ;shift constant
  79. _mutable        equ     $100            ;base address of mu-law table
  80. ;
  81.         move            a1,b            ;save input
  82.         lsl     a       #>_shift,x0     ;shift out sign bit, get shift constant
  83.         lsr     a       #_mutable,x1    ;shift in zero, get table base
  84.         tfr     x1,a    a1,x1           ;swap table base and offset
  85.         mac     x1,x0,a                 ;shift offset down and add to base
  86.         move            a,r0            ;move to address register
  87.         nop
  88.         lsl     b       x:(r0),a        ;c=sign bit, lookup linear data
  89.         neg     a       a,b             ;a=negative result, b=positive result
  90.         tcs     b,a                     ;if pos sign, correct result
  91.         endm
  92. ;
  93. ; allin - a-law to linear conversion
  94. ;
  95. allin   macro
  96. _shift  equ     $80                     ;shift constant
  97. _atable equ     $180                    ;base address of a-law table
  98. ;
  99.         move            a1,b            ;save input
  100.         lsl     a       #>_shift,x0     ;shift out sign bit, get shift constant
  101.         lsr     a       #_atable,x1     ;shift in zero, get table base
  102.         tfr     x1,a    a1,x1           ;swap table base and offset
  103.         mac     x1,x0,a                 ;shift offset down and add to base
  104.         move            a,r0            ;move to address register
  105.         nop
  106.         lsl     b       x:(r0),a        ;c=sign bit, lookup linear data
  107.         neg     a       a,b             ;a=negative result, b=positive result
  108.         tcs     b,a                     ;if positive sign, correct result
  109.         endm
  110.